Arena script

[Sa8Gecko]

This is a modified (almost completely different) version of the
script Rastavovich wrote for VIT BMP-3 Arena.
The Arena is a countermeasure system mounted on some
last generation russian tanks and apcs that should intercept
incoming missiles.
The Rastavovich original intercepts all incoming locked-on
missiles, but misses unguided rockets.
This one no. It could even intercept tank shells if fired at less
than 850m/s. I had to choose so high a speed cause
the Hellfires from AH-64 fly at more than 2700 km/h.
For this set of scripts to work you must:
create a init.sqs file with this line:
intercept = preprocessFile "intercept.sqf"
then place the following files in your mission directory:
VIT_arena.sqs
; usage: put this line in init field of each Arena units:
;
; [this] exec "VIT_arena.sqs"

_tank = _this select 0

_misArray =[]
_sectors = 8
_anglesect = 360 / _sectors
_hits = 3

_arena = (_hits ^ _sectors) -1
_i = 0
#check
? damage _tank > .95: exit
_pos = position _tank
#loop
_missile = NearestObject [(_pos select 0)+30*sin(_i),(_pos select 1)+30*cos(_i),5]
? (speed _missile)!=0:player globalchat format ["%1",speed _missile]
? (abs(speed _missile)> 300) && (abs(speed _missile)< 3000) && (!(_missile in _misArray)): goto "missile"
_i = _i + 23
? _i < 360: goto "loop"
_i =_i -360
@(true)
goto "check"
#missile
;@ (_tank distance _missile < 25 ||!alive _missile)
_misArray = _misArray +[_missile];_arena = [_missile,_tank,_arena,_anglesect,_hits] call intercept
hint "missile acquired"
goto "check"

intercept.sqf
private ["_dir","_tank","_missile","_arena","_mem","_angleapp","_anglesect","_hits","_check","_dist","_xone","_zmiss","_sectorapp","_vmissvert","_ttog","_vhoriz","_dummy"];

_missile = _this select 0;
_tank = _this select 1;
_arena =_this select 2;
_anglesect = _this select 3;
_hits = _this select 4;
_dir = ((getpos _tank select 0) - (getpos _missile select 0)) atan2 ((getpos _tank select 1) - (getpos _missile select 1));
if (_dir < 0) then {_dir = _dir + 360};

player globalchat format ["dir %1, mis %2 tank %3,dist %4", _dir,direction _missile, direction _tank,_missile distance _tank];

if (abs (_dir - (direction _missile)) < 155 && (alive _missile)) then {  
if ( abs (sin (_dir - (direction _missile)) * (_missile distance _tank))< 3.5) then {
player globalchat format ["horiz angle %1",abs (sin (_dir - (direction _missile)) * (_missile distance _tank))];
_angleapp =(direction _missile - direction _tank);
if (_angleapp < 0) then {_angleapp = _angleapp + 360};
player globalchat format ["angle %1",_angleapp];

_sectorapp = (_angleapp / _anglesect) - ((_angleapp / _anglesect) mod 1);
_check = (_arena / (_hits ^ _sectorapp)) - ((_arena  / (_hits ^ _sectorapp)) mod 1);

_mem = _check mod _hits;

player globalchat format ["sector %1, _mem %2",_sectorapp,_mem];
if (_mem != 0 ) then {
_dist = _tank distance _missile;
_xone = sqrt (((getpos _tank select 0) - (getpos _missile select 0))^2 + ((getpos _tank select 1) - (getpos _missile select 1))^2);
_zmiss = _dist * cos (asin (_xone / _dist)) ;

_vmissvert = (velocity _missile select 2);
if (_vmissvert == 0) then { _vmissvert = 0.01};
_ttog = _zmiss / ( - _vmissvert);
_vhoriz = sqrt ((velocity _missile select 0)^2 + (velocity _missile select 1)^2);

if ( (((_ttog * _vhoriz) > (_xone - 15)) || ((_ttog * _vhoriz) < (_xone +15))) ) then {
_dummy = "RKT_detonator" camcreate position _missile;
_dummy exec "deleteme.sqs";
_arena = _arena - (_hits ^ _sectorapp);
player globalchat format ["%1,%2,%3",typeOf _dummy,_arena,_missile distance _tank];
};
};
};
};
_arena
deleteme.sqs:
~.5
deletevehicle _this
exit

See intructions on top of VIT_arena.sqs.
It's full of globalchats cause are useful to track down data.
Remove them if they annoy you. This is a version I wrote
more than a year ago and never finished cause I started
working on MCAR. I modified it today, making it more
efficient. It's not finished yet, but fell free to modify it and use in your
mission. Ask me for help if needed, and eventual bugs.
If you plan to use it in your missions or addons, no need
to credit me. Only DON'T state the script is a fruit of your
own work when infact it's a fruit of MY own work.

Down there is the old, fully commented, version. Look at
it as reference. This ones intercepts only BIS missiles and
rockets, though.

[Sa8Gecko]


; modified by Sa8Gecko, with permission of Rastavovich
; (DO NOT mail Rastavovich for help, though)
; this intercept all BIS missiles (excluded LGB and AA ones), locked or not,
; no need for "incomingmissile" event handler
; so comment out the line calling it in config.cpp if you want to use it with VIT's BMP3 Arena
; version 1.91 required
;
; Tested with a PIVB 2,8 oc 3,15 in Everon, v 1.96: it works even on slower system, but not tested with
; great number of unit. ABSOLUTELY not tested in a multiplayer enviroment

; usage: put this line in init field of each Arena units:
;
; [this] exec "arena.sqs"
;
; providing the script is in the mission folder
; works with AKM74 (DKM) BMP 3 Arena: can work with any unit

; this is the first release of this script I would distribute.
; The scope is that someone steal the idea and make a better script,
; possibly eliminating the array thing.
; Please read through the comments before using this script.
; Feel free to modify and re-release at your will, please remember only to give credits
; to Rastavovich and 'Hudson & Pennywise'
; if you found any bug (and sure you'll find) report it in this forum or try to contact me via PM
; at the official forum, be advised though it could take some days before you'll get an answer

; bad thing: you have to write down the array with all the missiles/rockets
; you think AI or human player can shoot at Arena protected tanks.
; An impossible task given the number of custom addon missiles in
; circulation: willing mission makers could pass the array to the script
; via a global variable set at the start of mission, for example,
; if they know the weapons that will be used. Be careful not to enlarge the
; dimension of _ammoarray too much.
; Remember : the lower the dimension of the array, the better this script will work.
; If you are willing to write this array to use this script in your mission, but don't know
; how to retrieve ammo names nor you are easy with .pbo, put the unit you
; want to know which munitions it fires in the editor and put the following
; line in its initialization field:
;
; this addEventHandler ["fired", {hint format ["%1", _this select 4]}]
;
; I would not delete friendly ammo from the array: you know, friendly fire happens:
; sure if there aren't A-10 in your mission you can delete "Maverick" !
; With this method you can even stop bullets and cannon shells, if your PC is fast enough!

_ammoarray = ["RPG","LAW","AT3","CarlGustav","AT4","Hellfire","HellfireApach","Zuni","Rocket57","AT6","Maverick","Ch29T"]
_arrdim = count _ammoarray

_tank = _this select 0

; next number is equal to 3 raised to the 8th power - 1: it's not chosen at random,here follows
; an explanation: 8 is the number of sectors in which I divided the tank protected by the arena,
; I mean: the angle of 360 degrees surrounding the tank is divided in 8 sector of equal amplitude,
; 45 degrees. The number 3 is because each sector can be attacked two times before the third
; round can finally hit his target. So if I instead had wished a given spot attacked three times
; before the 4th round could finally hit and the sectors be 12, each of 30 degrees, I should have
; given _arena a value of 167772215 (4 ^ 12 -1). Or more simply write: _arena = (_hits ^ _sectors) -1
_arena = 6560

; as explained before _sectors is the number of sectors to be protected, _anglesect is the
; angle of each sector and it's set accordingly, _hits is how many times a given spot
; needs to be attacked to score a hit.

_sectors = 8
_anglesect = 360 / _sectors
_hits = 3

; note that if you subtract from _arena: (_hits raised to the n_th power) times (_hits -1),
; where n is a number between 0 and (_sectors -1), the n_th sector will be unprotected from
; the start: note that sectors starts from six o'clock (sector zero) and proceed in a
; clock-wise direction. In the same manner if you add (_hits raised to the n_th power) times x,
; where x is an integer, the n-th sector will have x more times plus the default ones before the
; same sector would be hit

; as stated above, if you uncomment next line (too lazy to do calculation), arena points
; will be calculated for you. In this case you can delete the former line setting _arena value
;
;_arena = (_hits ^ _sectors) -1
;
; be careful though: for example 36 sectors with _hits set to 3 is equal to 1.5009463 * 10 ^ 17 !
; In this case is best to reverse order and set _sectors to 3 and _hits to 36, but I think
; that such overprotected unit wouldn't be funny to play with

_sideunitl = 3.5
; above is set the variable containing the side lenght of the tank.
; About the 3.5 value: this was chosen because the longest side of the BMP 3
; fitted this value correctly. To compensate for a moving tank, I think this
; value should be raised a little. Otherwise more complex calculation
; considering the direction of movement of the tank itself should
; be implemented (speed is not enough, you need the velocity vector)

; main loop: this must be always in execution

#check
; if you comment out next line, the tank will protect itself even when dead
? damage _tank > .95: exit

; the following time interval is probably too short: anyway ...
~0.05

; variable that is needed to check each element of the array
_i = 0

; loop searching for known missiles approaching the arena system

#loop
_missile = NearestObject [_tank,_ammoarray select _i]

? ((typeof _missile) == (_ammoarray select _i)) : goto "missile"
_i = _i + 1
? _i < _arrdim: goto "loop"

goto "check"

; end of main loop. In case a missile has been detected,
; the next part checks if it is directing toward the tank

#missile

; calculates the direction of the missile object as regards the tank:
; it's needed to see if missile is aimed at the tank

_dir = ((getpos _tank select 0) - (getpos _missile select 0)) atan2 ((getpos _tank select 1) - (getpos _missile select 1))
? _dir < 0:_dir = _dir + 360

; if the missile is going in the opposite direction, then the tank is safe
; and no need to waste arena's ammo, this even in case a friendly unit fires in the
; vicinity of the tank (if it was a soldier in fact it would be dead rightly after
; having fired his RPG)


[Sa8Gecko]

2nd part, cause it couldn't stay in only one post:
? abs (_dir - (direction _missile)) > 155 : goto "check"
? abs (sin (_dir - (direction _missile)) * (_missile distance _tank))> _sideunitl :goto "check"

; if an incoming missile doesn't satisfy the condition above
; it is probably headed at the tank
; possible fault: two missile or RPG are launched almost simultaneously
; at the tank: one can be intercepted or left alone, but if the other
; was targeted right it could be too late before arena sets in, and damage
; may occur. Possible solution: divide this script in two parts, one checking
; for incoming rockets and the other doing the interception. Everytime a rocket
; is found (headed or not at the tank, that would be cleared by the other script)
; it is passed to the second script, so simultaneous interception could be carried
; out. Of course you need to return the new _arena value.

; if the missile is no more, look for another
? (!alive _missile) : goto "check"

; next lines I changed from Rastavovich's script, they check
; what direction (i.e. 9 o'clock, 4 o'clock and so on as to the tank)
; the missile is approaching
; Since they are left here, if the missile is not interceped
; because found to be heading for the stars, for example,
; an arena ammo will be wasted. This could be corrected moving
; them down the aforementioned calculation. The important thing is
; to leave them before destroying the inbound missile

; next line calculates the angle of the _tank approached by the missile
_angleapp =(direction _missile - direction _tank)
? _angleapp < 0: _angleapp = _angleapp + 360

; next one determine what sector of the _tank (of the available ones) is being attacked
_sectorapp = (_angleapp / _anglesect) - ((_angleapp / _anglesect) mod 1)

; _check is an integer number obtained dividing the remaining arena points by _hits raised to
; the _sectorapp-th power
_check = (_arena / (_hits ^ _sectorapp)) - ((_arena  / (_hits ^ _sectorapp)) mod 1)

; we need the remainder of the following division:
_rem = _check mod _hits

; if the remainder is equal to zero, it means that in that sector there aren't Arena
; ammo left, so better check for another missile and hope for the best...
? _rem == 0 : goto "check"


; now wait till the missile is close (I chose 20 meters, but
; the original value was 14), anyway don't lower this value
; this line could be commented out to save time, because nearestobject range
; should be about 25 meters
@ (_tank distance _missile < 20 ||!alive _missile)

; now tries to calculate if the missile will impact ground
; before reaching the target or is going to pass safely above it
; or instead if it's going dangerously near the tank.
; I was not very succesful, I mean, it works, but could be
; written better or replaced by a single line checking
; only the altitude of missile, or even discarded completely
; or perhaps replaced by a function, to decrease lag

_dist = _tank distance _missile
_xone = sqrt (((getpos _tank select 0) - (getpos _missile select 0))^2 + ((getpos _tank select 1) - (getpos _missile select 1))^2)
_zmiss = _dist * cos (asin (_xone / _dist))

_vmissvert = (velocity _missile select 2)
? _vmissvert == 0: _vmissvert = 0.01
_ttog = _zmiss / ( - _vmissvert)
_vhoriz = sqrt ((velocity _missile select 0)^2 + (velocity _missile select 1)^2)

? (((_ttog * _vhoriz) < (_xone - 15)) || ((_ttog * _vhoriz) > (_xone +15))) && (getpos _missile select 2) > 4: goto "check"

; if after all the above calculation the missile is no longer with us,
; look for another! Anyway I think it's a useless line that could be
; removed, if the missile isn't dead by now, it will be shortly
? !alive _missile : goto "check"

; You need Hudson & Pennywise F18: otherwise replace "Rad_Chaff" with
; another object (don't ask me, I can't think of any).
; Rastavovich replaced the real missile with another one placed
; on ground: the dummy one exploded because it touched the surface.
; I changed this because I was not satisfied with the way Rastavovich
; ( didn't ) made the missile detonate
_dummy = "Rad_Chaff" createvehicle position (_missile)

; if you haven't Hudson & Pennywise F18 installed, replace the former line with the following ones:
;
; _dummy = typeof _missile createvehicle [getpos _missile select 0, getpos _missile select 1]
; deletevehicle _missile
;
; and delete the line 'deletevehicle _dummy', which should be unuseful at that moment
; In this way obviously the missile will no more explode in mid-air, but his substitute
; will do that on the ground

; next waits a little and get rid of _dummy, don't want see it
; floating to the ground
~.1
deletevehicle _dummy

; as usual, repeat the search, in the meantime the sector attacked is being updated
_arena = _arena - (_hits ^ _sectorapp)
goto "check"